Autor Wątek: Kamoso-frameworks-git  (Przeczytany 1716 razy)

0 użytkowników i 1 Gość przegląda ten wątek.

pavbaranov

  • Administrator
  • Ekspert
  • *****
  • Wiadomości: 848
  • Reputacja +25/-0
  • Architektura: x86_64
  • DE/WM: KF5.16+Plasma5.4.95+KDEApps 15.11.80+git na KF5
  • Distro: Arch Linux
  • GPU: Radeon free
  • Kernel: 4.3 (BFQ/CK/BLD/UKSM/+optymalizacje)
Kamoso-frameworks-git
« dnia: Luty 28, 2015, 09:09:54 »
W AUR brakuje paczki Kamoso, tymczasem została ona w całości przeportowana do KF5, buduje się poprawnie i działa. Przedstawiam zatem PKGBUILD umożliwiający jej stworzenie. Zanim jednak przystąpicie do budowy Kamoso, musicie zbudować inną paczkę, a mianowicie purpose, której również nie ma w repozytoriach. Dlatego też podaję również PKGBUILD umożliwiający utworzenie purpose (w wersji -git, bowiem nie ma jeszcze wersji stabilnej w KF).

purpose-git
PKGBUILD
# Maintainer: pavbaranov
pkgname=purpose-git
pkgver=r87.d478d07
pkgrel=1
pkgdesc="Framework for providing abstractions to get the developer's purposes fulfilled."
arch=('x86_64')
url='http://quickgit.kde.org/?p=purpose.git'
license=('GPL' 'LGPL' 'FDL')
depends=('kcoreaddons' 'kconfig' 'kdeclarative' 'ki18n')
makedepends=('extra-cmake-modules' 'kdoctools' 'git')
#groups=('')
source=("git://anongit.kde.org/purpose")
md5sums=('SKIP')
_gitpkgname=purpose

pkgver() {
  cd purpose
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    mkdir -p build
}

build() {
  cd build
 
  cmake ../${_gitpkgname} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DPLUGIN_INSTALL_DIR=/usr/lib/qt5/plugins \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}

kamoso-frameworks-git
PKGBUILD
# Maintainer: pavbaranov

_gitpkgname=kamoso
pkgname=$_gitpkgname-frameworks-git
pkgver=r857.b0dfb87
pkgrel=1
pkgdesc="Kamoso is an application to take pictures and videos out of your webcam."
url="https://projects.kde.org/projects/extragear/multimedia/kamoso"
arch=('i686' 'x86_64')
license=('GPL')
#depends=('extra-cmake-modules' 'qt5-base'  'qt-gstreamer' 'libkipi')
depends=('kconfig' 'kconfigwidgets' 'kcompletion' 'kwidgetsaddons' 'kio' 'solid'
         'kdeclarative' 'systemd' 'gst-plugins-base' 'gst-plugins-good' 'qt5-gstreamer'
         'kipi-plugins-frameworks-git' 'phonon-qt5' 'qt5-graphicaleffects' 'purpose-git')
makedepends=('extra-cmake-modules' 'git' 'boost' 'kdoctools')
conflicts=('kamoso')
provides=('kamoso')

source=("git://anongit.kde.org/kamoso.git#branch=frameworks")
sha256sums=('SKIP')

pkgver() {
        cd kamoso
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
        mkdir -p build
}

build() {
        cd build
        cmake ../$_gitpkgname \
                -DCMAKE_INSTALL_PREFIX=/usr \
                -DCMAKE_BUILD_TYPE=Release \
                -DLIB_INSTALL_DIR=lib \
                -DPLUGIN_INSTALL_DIR=/usr/lib/qt5/plugins \
                -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
                -DBUILD_TESTING=OFF
        make
}

package() {
        cd build
        make DESTDIR="$pkgdir" install
}

 

Polityka cookies
Darmowe Fora | Darmowe Forum
psy japonia darmowefora horses isztar