Projekty/Wsparcie > POLAUR

Person-Viewer czyli przeglądarka kontaktów

(1/1)

pavbaranov:
Działa w Plasma 5. Wymaga uprzedniej instalacji libkfbapi-git z AUR.
PKGBUILD

--- Kod: ---# Maintainer: pavbaranov

pkgname=personviewer-frameworks-git
pkgver=r111.77fccdd
pkgrel=1
pkgdesc='Simple address book application displaying info about aggregated contacts'
arch=('i686' 'x86_64')
url='http://quickgit.kde.org/?p=person-viewer.git'
license=('GPL')
depends=('kdelibs4support' 'kwidgetsaddons' 'kpeople' 'libkfbapi-git' 'gettext' 'python')
makedepends=('extra-cmake-modules' 'git')
install=personviewer-frameworks.install
source=("git://anongit.kde.org/person-viewer.git#branch=frameworks")
sha256sums=('SKIP')

pkgver() {
  cd person-viewer
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../person-viewer \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
--- Koniec kodu ---
personviewer-frameworks.install

--- Kod: ---post_install() {
    update-desktop-database -q
    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
}

post_update() {
    post_install
}

post_remove() {
    post_install
}
--- Koniec kodu ---

Nawigacja

[0] Indeks wiadomości