Autor Wątek: Ark dla Plasma5  (Przeczytany 1185 razy)

0 użytkowników i 1 Gość przegląda ten wątek.

pavbaranov

  • Administrator
  • Ekspert
  • *****
  • Wiadomości: 848
  • Reputacja +25/-0
  • Architektura: x86_64
  • DE/WM: KF5.16+Plasma5.4.95+KDEApps 15.11.80+git na KF5
  • Distro: Arch Linux
  • GPU: Radeon free
  • Kernel: 4.3 (BFQ/CK/BLD/UKSM/+optymalizacje)
Ark dla Plasma5
« dnia: Styczeń 05, 2015, 18:01:02 »
Poniższy sposób proszę również traktować jako swego rodzaju eksperyment (dlaczego opisałem tu: http://www.archlike.darmowefora.pl/index.php/topic,178.0.html; ta paczka buduje się w analogiczny sposób)
PKGBUILD
# Maintainer: Antonio Rojas
# Maintainer for build agaist of stable KF5: pavbaranov

pkgname=ark-frameworks-git
pkgver=r2769.8f91da6
pkgrel=1
pkgdesc='Archiving Tool'
arch=('i686' 'x86_64')
url='http://kde.org/applications/utilities/ark/'
license=('GPL')
depends=('kpty' 'kdelibs4support' 'khtml' 'libkonq-frameworks' 'libarchive')
makedepends=('extra-cmake-modules' 'git' 'kdoctools' 'python')
optdepends=('p7zip' 'zip' 'unzip' 'unrar')
conflicts=('kdeutils-ark' 'ark')
provides=('ark')
install=$pkgname.install
source=("git://anongit.kde.org/ark.git#branch=frameworks")
sha256sums=('SKIP')

pkgver() {
  cd ark
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../ark \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
ark-frameworks-git.install
post_install() {
    update-desktop-database -q
    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
}

post_update() {
    post_install
}

post_remove() {
    post_install
}

EDIT:
Od wersji 15.08 nie ma już potrzeby kompilacji. Wersja beta (15.07.80) jest już dostępna w [kde-unstable].
« Ostatnia zmiana: Lipiec 29, 2015, 08:01:43 wysłana przez pavbaranov »

 

Polityka cookies
Darmowe Fora | Darmowe Forum
proskills blanciormt2forum piecfrakcji riderstigers cesarstwoniemieckie